cmake_minimum_required(VERSION 3.5)
project(grid_map_visualization)

## Find libraries
find_package(ament_cmake REQUIRED)
find_package(grid_map_cmake_helpers REQUIRED)
find_package(grid_map_core REQUIRED)
find_package(grid_map_msgs REQUIRED)
find_package(grid_map_ros REQUIRED)
find_package(nav_msgs REQUIRED)
find_package(rclcpp REQUIRED)
find_package(sensor_msgs REQUIRED)
find_package(visualization_msgs REQUIRED)
find_package(Eigen3 REQUIRED)

grid_map_package()

set(dependencies
  grid_map_core
  grid_map_msgs
  grid_map_ros
  nav_msgs
  rclcpp
  sensor_msgs
  visualization_msgs
)

###########
## Build ##
###########

## Specify additional locations of header files
include_directories(
  include
  SYSTEM
    ${EIGEN3_INCLUDE_DIR}
)

set(library_name ${PROJECT_NAME}_core)

## Declare a cpp library
add_library(${library_name} SHARED
  src/GridMapVisualization.cpp
  src/GridMapVisualizationHelpers.cpp
  src/visualizations/FlatPointCloudVisualization.cpp
  src/visualizations/GridCellsVisualization.cpp
  src/visualizations/MapRegionVisualization.cpp
  src/visualizations/OccupancyGridVisualization.cpp
  src/visualizations/PointCloudVisualization.cpp
  src/visualizations/VectorVisualization.cpp
  src/visualizations/VisualizationFactory.cpp
  src/visualizations/VisualizationBase.cpp
)

ament_target_dependencies(${library_name} SYSTEM
  ${dependencies}
)

# Declare cpp node executable
add_executable(${PROJECT_NAME}
  src/grid_map_visualization_node.cpp
)

## Specify libraries to link executable target against
target_link_libraries(${PROJECT_NAME} ${library_name})

ament_target_dependencies(${PROJECT_NAME} SYSTEM
  ${dependencies}
)

#############
## Install ##
#############

# Mark executables and/or libraries for installation
install(TARGETS ${library_name}
  ARCHIVE DESTINATION lib
  LIBRARY DESTINATION lib
  RUNTIME DESTINATION bin
)

install(TARGETS ${PROJECT_NAME}
  RUNTIME DESTINATION lib/${PROJECT_NAME}
)

# Mark other files for installation
install(
  DIRECTORY doc
  DESTINATION share/${PROJECT_NAME}
)

#############
## Testing ##
#############

if(BUILD_TESTING)
  # Linting is setup this way to add a filter
  # to ament_cpplint to ignore the lack of
  # copyright messages at the top of files.
  # Copyright messages are being checked for by both
  # ament_cmake_cpplint & ament_cmake_copyright.

  find_package(ament_lint_auto REQUIRED)
  find_package(ament_lint_auto QUIET)
  if(ament_lint_auto_FOUND)
    # exclude copyright checks
    list(APPEND AMENT_LINT_AUTO_EXCLUDE
      ament_cmake_cpplint
      ament_cmake_copyright
    )
    ament_lint_auto_find_test_dependencies()

    # run cpplint without copyright filter
    find_package(ament_cmake_cpplint)
    ament_cpplint(
      FILTERS -legal/copyright -build/include_order
    )
  endif()
  ament_lint_auto_find_test_dependencies()
endif()

ament_export_include_directories(include)
ament_export_libraries(${library_name})
ament_export_dependencies(${dependencies})
ament_package()
